Submission 488cdbc9...

ChallengeInteger sorting
Submitterhyszeth.eth
Submitted at2018-11-17
Gas used810236
/**
 * This file is part of the 1st Solidity Gas Golfing Contest.
 *
 * This work is licensed under Creative Commons Attribution ShareAlike 3.0.
 * https://creativecommons.org/licenses/by-sa/3.0/
 *
 * Author: Greg Hysen (@hysz)
 * Date: June, 2018
 */

pragma solidity 0.4.24;

contract Sort {

    /**
     * @dev Sorts a list of integers in ascending order.
     *
     * The input list may be of any length.
     *
     * @param input The list of integers to sort.
     * @return The sorted list.
     */
     function sort(uint[] input)
      public
      pure
      returns(uint[])
    {
        if(input.length == 0) return input;
        quickSort(input, 0, input.length - 1);
        return input;
     }

        function quickSort(
            uint[] input,
            uint lo,
            uint hi
        )
         internal
         pure
        {
            uint iElem;
            uint jElem;

            while(lo < hi) {
                if(hi - lo < 10) {
                    // If within threshold, run insertion sort instead.
                    for(i = lo + 1; i <= hi; i++) {
                        j = i;
                        jElem=input[j];
                        while(j > lo && (iElem=input[j-1]) > jElem) {
                            input[j--] = iElem;
                        }
                        if(j != i) input[j] = jElem;
                    }
                    return;
                }

                // Pivot
                uint pivot = input[uint((hi+lo)/2)];
                uint i = lo - 1;
                uint j = hi + 1;
                while(true) {
                    while((iElem=input[uint(++i)]) < pivot) {}
                    while((jElem=input[uint(--j)]) > pivot) {}

                    if(i >= j) break;
                    (input[uint(i)], input[uint(j)]) = (jElem, iElem);
                }

                // Sort
                if(j - lo < hi - j) {
                    quickSort(input, lo, j);
                    lo = j+1;
                } else {
                    quickSort(input, j + 1, hi);
                    hi = j;
                }
            }
        }
}